Подключение пьезопищалки и генерация звука. Функции tone() и noTone()
Сегодня мы поговорим о том, как воспроизводить мелодии и отдельные звуки с помощью платы Arduino, применяя функции tone() и noTone().
Элемент, который используется для примера в данной статье, называется пьезопищалка, он же зуммер, он же пьезодинамик.
Ранее мы научились подключать к плате светодиод и познакомились с функциями digitalWrite() и delay(). С их помощью можно подавать напряжение на пины контроллера и приостанавливать выполнение программы. Эти функции здесь тоже пригодятся.
Для чего нам звуки
Любой робот или другое электронное устройство становятся проще в использовании, если имеют возможность сигнализировать о своем состоянии. Для индикации могут использоваться световые или акустические элементы.
К примеру, известный робот R2-D2 использовал оба типа обратной связи — он мигал и издавал странные звуки.
Для начала разберемся, как работает пьезопищалка. Очевидно, что она должна издавать звук. Но что это и как возникает?
Что такое звук
Звук — это колебания воздуха, которые волнами расходятся от своего источника. Волны эти не видны, однако воздействуют на барабанные перепонки, вызывая в них механические колебания, которые мозг человека умеет преобразовывать в звуки.
Получается, чтобы появились колебания и возник аудиосигнал, пьезопищалка должна двигаться и воздействовать на воздух.
Так оно и есть. Пьезодинамик может совершать маленькие, незаметные для глаз движения под воздействием электричества. Мы их не увидим, однако воздух колебать они могут, а значит будет издаваться звук.
Имея в своем распоряжении Arduino, мы можем использовать электричество и подавать напряжение на пищалку по определенной программе.
Как извлечь звук из пьезопищалки
Если подключить пьезопищалку напрямую к батарейному отсеку и подать постоянный ток на пластину, то ничего не произойдёт. Попробуем подключить ее к какому-нибудь D-пину и GND нашего Arduino.
Но сначала нужно загрузить в плату программу, которая будет управлять напряжением на этом пине:
void setup() {
pinMode(6, OUTPUT); // задаем режим подачи напряжения на пин 6
}
void loop() {
digitalWrite(6, HIGH); // подаем напряжение на пин 6
delay(500); // ждем 500 миллисекунд
digitalWrite(6, LOW); // выключаем напряжение на пине 6
delay(500); // ждем 500 миллисекунд
}
Итак, код залит в плату. Присоединяем новый элемент.
Настройка звучания сигнала
Если все сделано, как описано выше, то должны быть слышны щелчки.
Мы установили чередование подачи и отключения напряжения с длительностью в 500 тысячных долей секунды через параметр функции delay(). Поэтому звук длится полсекунды, после чего на такой же отрезок времени затихает.
Чтобы колебания происходили быстрее, то есть чаще, нужно уменьшить время задержки.
Поэкспериментируйте с разными значениями для функции delay(). Попробуйте выставить в программе вместо 500 числа 10, 5, 1.
void setup() {
pinMode(6, OUTPUT);
}
void loop() {
digitalWrite(6, HIGH);
delay(10);
digitalWrite(6, LOW);
delay(10);
}Чем чаще происходят колебания, тем выше звук, который мы слышим. Получается, если увеличивать частоту, звук будет превращаться в тонкий писк. А если уменьшать — в гул или гудение.
Кстати, именно поэтому мы слышим писк, когда рядом летает комар. Он часто-часто машет своими крылышками. В противовес ему — полет шмеля, который гораздо тяжелее и медленнее, поэтому он как бы “гудит”.
Как рождается мелодия
Для вопроизведения последовательности звуков, то есть мелодии, поможет функция tone().
Ее параметры дают возможность управлять направлением сигнала (какой из пинов на контроллере должен быть задействован) и частотой колебаний звука.
Запись функции выглядит так:
tone( Номер пина , Частота );Номер пина здесь — это тот пин Arduino, куда подключена пьезопищалка, из которой хотим извлечь звук. А частота — требуемое значение частоты в герцах (положительное целое число).
Пример программы с функцией tone():
void setup() {
pinMode(6, OUTPUT);
}
void loop() {
tone(6, 50); // подаем аудиосигнал с частотой 50 Гц на пин 6
}При загрузке и запуске данного кода можно получить звук, если к указанному пину подключена пьезопищалка или другое акустическое устройство.
Серия из команд с различными частотами для одного пина позволит нашему Arduino сыграть мелодию, последовательно сменяя один тон на другой.
Одним из применений может стать установка музыкального приветствия на запуск робота:
void setup() {
pinMode(6, OUTPUT);
tone(6, 65);
delay(300);
tone(6, 87);
delay(300);
tone(6, 65);
delay(300);
}
void loop() {
}Горшочек, не вари!
Функция tone() по умолчанию воспроизводит звук нужной частоты без конечного срока, то есть бесконечно. Чтобы прервать его, требуется использовать противоположную по значению операцию — noTone().
У этой функции лишь один параметр — указание нужного пина.
noTone( Номер пина );Если на выбранном пине воспроизводится звук, он будет приостановлен. Если же генерации сигнала там не было, то функция ничего не сделает, и программа пойдет дальше.
С небольшими изменениями предыдущий пример превращается в код для мелодии приветствия нашего робота:
void setup() {
pinMode(6, OUTPUT);
tone(6, 65);
delay(300);
tone(6, 87);
delay(300);
tone(6, 65);
delay(300);
noTone(6);
}
void loop() {
}Обратите внимание, что при использовании нескольких пьезопищалок нужно сначала подавать noTone() на пин, где уже были активированы колебания, и только потом вызывать tone() на другой пин.
Пример мелодии для пьезопищалки
const int c = 261;
const int d = 294;
const int e = 329;
const int f = 349;
const int g = 391;
const int gS = 415;
const int a = 440;
const int aS = 455;
const int b = 466;
const int cH = 523;
const int cSH = 554;
const int dH = 587;
const int dSH = 622;
const int eH = 659;
const int fH = 698;
const int fSH = 740;
const int gH = 784;
const int gSH = 830;
const int aH = 880;
const int buzzerPin = 8;
const int ledPin1 = 12;
const int ledPin2 = 13;
int counter = 0;
void setup()
{
pinMode(buzzerPin, OUTPUT);
pinMode(ledPin1, OUTPUT);
pinMode(ledPin2, OUTPUT);
}
void loop()
{
firstSection();
secondSection();
beep(f, 250);
beep(gS, 500);
beep(f, 350);
beep(a, 125);
beep(cH, 500);
beep(a, 375);
beep(cH, 125);
beep(eH, 650);
delay(500);
secondSection();
beep(f, 250);
beep(gS, 500);
beep(f, 375);
beep(cH, 125);
beep(a, 500);
beep(f, 375);
beep(cH, 125);
beep(a, 650);
delay(650);
}
void beep(int note, int duration)
{
tone(buzzerPin, note, duration);
if(counter % 2 == 0)
{
digitalWrite(ledPin1, HIGH);
delay(duration);
digitalWrite(ledPin1, LOW);
}else
{
digitalWrite(ledPin2, HIGH);
delay(duration);
digitalWrite(ledPin2, LOW);
}
noTone(buzzerPin);
delay(50);
counter++;
}
void firstSection()
{
beep(a, 500);
beep(a, 500);
beep(a, 500);
beep(f, 350);
beep(cH, 150);
beep(a, 500);
beep(f, 350);
beep(cH, 150);
beep(a, 650);
delay(500);
beep(eH, 500);
beep(eH, 500);
beep(eH, 500);
beep(fH, 350);
beep(cH, 150);
beep(gS, 500);
beep(f, 350);
beep(cH, 150);
beep(a, 650);
delay(500);
}
void secondSection()
{
beep(aH, 500);
beep(a, 300);
beep(a, 150);
beep(aH, 500);
beep(gSH, 325);
beep(gH, 175);
beep(fSH, 125);
beep(fH, 125);
beep(fSH, 250);
delay(325);
beep(aS, 250);
beep(dSH, 500);
beep(dH, 325);
beep(cSH, 175);
beep(cH, 125);
beep(b, 125);
beep(cH, 250);
delay(350);
}Курсы Робикс, в которых изучается этот материал
- Занятия по робототехнике для дошкольников Робикс: 0-й уровень, STEM
- Робикс: 1-й уровень
- Робикс: 2-й уровень. «Робот линии»
Добавить комментарий